      SUBROUTINE CSCAL( N, CA, CX, INCX )
*
*     scales a vector by a constant.
*     jack dongarra, linpack,  3/11/78.
*
*     .. Scalar Arguments ..
      INTEGER           INCX, N
      COMPLEX           CA
*     ..
*     .. Array Arguments ..
      COMPLEX           CX( 1 )
*     ..
*     .. Local Scalars ..
      INTEGER           I, IX, NINCX
*     ..
*     .. Executable Statements ..
*
      IF( N.LE.0 )
     $   RETURN
      IF( INCX.EQ.1 )
     $   GO TO 20
*
*        code for increment not equal to 1
*
      IX = 1
      IF( INCX.LT.0 )
     $   IX = 1 - ( N-1 )*INCX
      NINCX = IX + ( N-1 )*INCX
      DO 10 I = IX, NINCX, INCX
         CX( I ) = CA*CX( I )
   10 CONTINUE
      RETURN
*
*        code for increment equal to 1
*
   20 DO 30 I = 1, N
         CX( I ) = CA*CX( I )
   30 CONTINUE
      RETURN
      END
